Utilisation : Les liens ne sont pas apparents. Pour obtenir des informations sur un mot clé, cliquez-le dans le script !

Cette image nécessite la création de "crater_dat" en utilisant le script "crater_dat.pov" que nous présentons en premier.

// Persistence Of Vision raytracer version 3.5 sample file.
// CRATER_DAT.POV
// Render CRATER_DAT.POV (this file) to create the height_field
// image that is needed in CRATER.POV. Then render CRATER.POV.
// 
// ( You can use any output image type, but the quality will be
// best with the special 16-bit gray output that is supported
// by the PNG, TGA and PPM image types. For example the command
// line setting +fn will set the output image type to PNG. See
// the documentation for details.)

global_settings {assumed_gamma 2.2 hf_gray_16}

#include "colors.inc"

// a wrinkle colored plane

plane {z,10
	hollow on
	pigment {wrinkles
		color_map {
			[0 White*0.3]
			[1 White]
		}
	}
}

// Main spotlight creates crater mountain
light_source {0 color 1 spotlight point_at z*10
	radius 7 falloff 11
}

// Dim spotlight softens outer edges further
light_source {0 color .25 spotlight point_at z*10
	radius 2 falloff 15
}

// Narrow spotlight creates central peak
light_source {0 color .1 spotlight point_at z*10
	radius 0 falloff 1.3
}

// Negative spotlight cuts out crater insides
light_source {0 color -0.9 spotlight point_at z*10
	radius 5 falloff 9.5
}

// Dim negative spotlight counteracts dim positive light in center
light_source {0 color -.25 spotlight point_at z*10
	radius 3 falloff 8
}

Voici ce que nous donne la génération de "crater_dat :

Et voici le script de génération de la scène :

// Persistence Of Vision raytracer version 3.5 sample file.
// CRATER.POV
// Render CRATER_DAT.POV to create the height_field image that
// is needed in CRATER.POV (this file). Then render this file.
// 
// ( When CRATER.POV is rendered, the output image type must be
// the same as when CRATER_DAT.POV was rendered. That is how it
// works when no image type is specified in the height_field.
// Alternatively you can specify the image type of the
// height_field object in line 23 in this file. See the
// documentation for details.)

global_settings {assumed_gamma 2.2}

#include "colors.inc"

camera {location <0, 8,-20> direction z*5 look_at 0}

light_source {<1000, 1000,-1000> White}

height_field {
	"crater_dat" smooth
	pigment {White}
	translate <-.5, 0,-.5>
	scale <17, 1.75, 17>
}

Et voici ce que nous obtenons :