3.3.8 Les groupes de lumières

Les groupes d'éclairage rendent possible la création d'union de sources de lumière et d'objets, où les objets du groupe sont illuminés par les lumières du groupe ou, si désiré, aussi par les sources de lumière globales. Les sources de lumière du groupe ne peuvent illuminer que les objets de ce groupe.

Les groupes d'éclairage sont utiles, par exemple, lors de la création de scènes où certains objets ont tendance à devenir trop sombres alors que la luminosité d'ensemble est exactement celle désirée, puisque les sources de lumière dans le groupe ne contribuent pas à l'éclairage global.

Syntaxe :

light_group {
	LIGHT_GROUP LIGHT  |
	LIGHT_GROUP OBJECT |
	LIGHT_GROUP
	[LIGHT_GROUP MODIFIER]
}
LIGHT_GROUP LIGHT:
	light_source | light_source IDENTIFIER
LIGHT_GROUP OBJECT: 
	OBJECT | OBJECT IDENTIFIER
LIGHT_GROUP MODIFIER:
	global_lights BOOL | TRANSFORMATION

global_lights. Ajoutez cette commande au groupe pour avoir les objets également éclairés par les sources de lumières globales.

Les groupes d'éclairage peuvent être emboîtés. Dans ce cas les groupes d'éclairage héritent des sources de lumière du groupe conteneur.

Les groupes d'éclairage peuvent être vus comme une 'union d'un objet et d'une source de lumière' et peuvent être utilisés dans les CSG.

Exemples, groupe d'éclairage simple :

#declare RedLight = light_source {
	<-500, 500,-500>
	rgb <1, 0, 0>
}

light_group {
	light_source {RedLight}
	sphere {0, 1 pigment {rgb 1}}
	global_lights off
}

Groupe d'éclairage emboîté :

#declare L1 = light_group {
	light_source {<10, 10, 0>, rgb <1, 0, 0>}
	light_source {<0, 0,-100>, rgb <0, 0, 1>}
	sphere {0, 1 pigment {rgb 1}}
}

light_group {
	light_source {<0, 100, 0>, rgb 0.5}
	light_group {L1}
}

Groupe d'éclairage dans une CSG:

difference {
	light_group {
		sphere {0, 1 pigment {rgb 1}}
		light_source {<-100, 0,-100> rgb <1, 0, 0>}
		global_lights off
	}
	light_group {
		sphere {<0, 1, 0>, 1 pigment {rgb 1}}
		light_source {<100, 100, 0> rgb <0, 0, 1>}
		global_lights off
	}
	rotate <-45, 0, 0>
}

Dans le dernier exemple, le résultat sera une sphère illuminée de rouge, avec la partie de la différence illuminée en bleu. Résultat comparable à la différence entre deux sphères avec un pigment différent.

3.3.7 Les sources de lumière

3.3.9 Les modificateurs d'objet