2.2.6.1 Utilisation de la tache focale

Construisons une simple scène pour illustrer l'utilisation de la tache focale. Pour cet exemple, nous utiliserons une sphère rose, une boîte verte et un cylindre bleu, avec la sphère en avant-plan, la boîte au centre et le cylindre en arrière-plan. Un plancher en damier pour la perspective et un couple de sources de lumière compléteront la scène. Nous créons un nouveau fichier appelé focaldem.pov et entrons le texte suivant :

#include "colors.inc"
#include "shapes.inc"
#include "textures.inc"
sphere {
	<1, 0,-6>, 0.5
	finish {
		ambient 0.1
		diffuse 0.6
	}
	pigment {NeonPink}
}
box {
	<-1,-1,-1>, <1, 1, 1>
	rotate <0,-20, 0>
	finish {
		ambient 0.1
		diffuse 0.6
	}
	pigment {Green}
}
cylinder {
	<-6, 6, 30>, <-6,-1, 30>, 3
	finish {
		ambient 0.1
		diffuse 0.6
	}
	pigment {NeonBlue}
}
plane {
	y,-1.0
	pigment {
		checker color Gray65 color Gray30
	}
}
light_source {<5, 30,-30> color White}
light_source {<-5, 30,-30> color White}

Maintenant nous pouvons placer notre caméra à tache focale en un endroit approprié. Franchement en arrière de nos trois objets, nous aurons une belle vue. L'ajustement du point de focale le placera n'importe où dans la scène. Nous ajoutons seulement les lignes suivantes :

camera {
	location <0.0, 1.0,-10.0>
	look_at <0.0, 1.0, 0.0>
	// focal_point <-6, 1, 30>	// cylindre bleu dans la focale
	// focal_point <0, 1, 0>	// boîte verte dans la focale
	focal_point <1, 1,-6>	// sphère rose dans la focale
	aperture 0.4	// un joli compromis
	// aperture 0.05	// tout est dans la focale
	// aperture 1.5	// plus brouillé
	// blur_samples 4	// peu d'échantillons, plus rapide à rendre
	blur_samples 20	// plus d'échantillons, meilleure qualité d'image
}

Le point de focale est simplement le point où la focale de la caméra est la plus pointue. Nous positionnons ce point et assignons une valeur à l'ouverture (aperture) pour dire de quelle manière, proche ou éloignée, nous voulons que la tache focale arrive sur la zone de focale.

La définition de l'ouverture peut être considérée comme l'aire de focale. Agrandir l'ouverture rend l'aire de focale plus petite et inversement. Voici comment nous contrôlons la façon dont la tâche focale s'approche du point de focale.

La définition du nombre d'échantillons sur la tâche indique combien de rayons sont utilisés pour chaque pixel. En conclusion, plus de rayons sont utilisés, et plus la qualité de l'image est grande, mais plus elle est longue à rendre. Chaque scène est différente, aussi devons nous expérimenter. Ce didacticiel a les exemples pour 4 et 20 échantillons, mais nous pouvons en utiliser plus pour des images de haute qualité. Nous ne devons pas utiliser plus d'échantillons que nécessaire pour atteindre la qualité désirée - plus d'échantillonnage utilise plus de temps. Les différents paramétrages de confidence et de variance sont étudiés dans la section "Tache focale".

Nous expérimentons le point de focale, l'ouverture et l'échantillonnage. La scène a des lignes avec d'autres valeurs, que nous pouvons tester en enlevant les doubles barres inclinées de commentaire, et en plaçant ces caractères de commentaire devant les lignes à occulter. Nous ne faisons qu'un changement à la fois, pour bien en percevoir l'effet sur la scène.

Deux derniers points quand on rend une scène avec une caméra à tache focale. Nous n'avons pas besoin de spécifier l'anti-crénelage car ce code utilise sa propre méthode d'échantillonnage qui s'occupe automatiquement de l'anti-crénelage. Enfin, la tache focale ne peut être utilisée qu'avec des caméras à perspective.